(одна процедура) Вывод КВАДРАТА 8на8 каким-то цветом ,  заданным в D
	// т.е. выводит два байта рядом (это пискселей по четыре, всего 8), цветом D
	// HL - начальная точка должно быть не менее $4000!  адрес $4000 равен первыми 4 пикселам нулевой строки

L8DC2:
                    Xra A		// A:=0
                    Out 0C2h 		//  A на порт  C2 =0 - влючаем страницу Видео ОЗУ

                    Mvi E, 008h 		// E=8 - высота спрайта Y
                    Lxi B, 0003Fh 	// BC=63 байтов, (63 байт =ОДНА строка! - потому что по 4 пикселя) ( =63 - для смешения на туже позицию в только в нижней строке)) (от 0..63 )

L8DCA: 	//Цикл
                    Mov M,D 	// mem[HL]=D // D - цвет сразу 4 пикселей!
                    Inx H  		// HL=HL+1 следующий байт рядом
                    Mov M,D 	// mem[HL]=D тоже цветом  D //D - цвет сразу 4 пикселей!
                    Dad B 		//HL=HL+BC {смещаем под тот же байт по X только в нижней строке}
                    Dcr E 		// E=E-1
                    JNZ L8DCA // если (E<>0) т.е. не все стороки выведено перейти L8DCA

                    Mvi A, 002h // A:=2
                    Out 0C2h //  A на порт  C2 =2 - ВЫКлючаем страницу Видео ОЗУ
                    RET

Давай я тебе чорновик паскалем это так
Procedure Kvadrat; // d - цвет
Label m1;
Begin
VIDEOon;
E=8; BC=63;

m1:
Video[HL]=D; // D - цвет сразу 4 пикселей!
HL:=HL+1;
Video[HL]=D;// ... и рядом 4пискела, D - цвет сразу 4 пикселей!

HL=HL+BC {смещаем под тот же байт по X только в нижней 
E:=E-1;
If E <> 0 then  m1;

VIDEOoff;
end;

(вторая процедура) вывод СПРАЙТА т.е. из одной области байты вдругую (в видел
// DE - адрес начала спрайта 8 на 8
//HL - адрес в ВидеоОЗУ (+$4000 смещение)

L8DD7:
                    Xra A		// A:=0
                    Out 0C2h  		//  A на порт  C2 =0 - влючаем страницу Видео ОЗУ
                    Mvi B, 008h // B=8 //счетчик строк

L8DDC:
                    Ldax D		//A=mem[DE] - читаем байт спрайта
                    Mov M,A 	//mem[HL]=A - толкаем байт в  Видео ОЗУ
                    Inx H 		// HL=HL+1
                    Inx D      // DE=DE+1

      //повторяем 4 пискела рядом! Ну это исключительно из моей игрушки
                    Ldax D //A=mem[DE] - читаем байт спрайта
                    Mov M,A //mem[HL]=A - толкаем байт в  Видео ОЗУ
                     Inx H // HL=HL+1
                    Inx D    // DE=DE+1

                    Push D // сохраним позицию DE в стек
                    Lxi D, 0003Eh // DE=62 смещение на нижнюю строку
                    Dad D  	/// HL=HL+DE прибавили это смещение 
                    Pop D // вернули DE из стека
                    Dcr B // B=B-1 // счетчик строк

                    JNZ L8DDC // если   B<>0 then L8DDC

                    Mvi A, 002h // A:=2
                    Out 0C2h 	//  A на порт  C2 =2 - ВЫКлючаем страницу Видео ОЗУ
                    RET